cmake_minimum_required(VERSION 3.13)
project(rrcc)

set(CMAKE_CXX_STANDARD 14)

# Compilation step for static resources
FUNCTION(ADD_RESOURCES out_var)
    SET(result)
    FOREACH(in_f ${ARGN})
        FILE(RELATIVE_PATH src_f ${CMAKE_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/${in_f})
        SET(out_f "${PROJECT_BINARY_DIR}/${in_f}.o")
        get_filename_component(out_d ${out_f} DIRECTORY)
        FILE(MAKE_DIRECTORY ${out_d})
        ADD_CUSTOM_COMMAND(OUTPUT ${out_f}
                COMMAND ld --relocatable --format binary --output ${out_f} ${src_f}
                DEPENDS ${in_f}
                WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
                COMMENT "Embedding object ${src_f} into ${out_f}"
                VERBATIM
                )
        LIST(APPEND result ${out_f})
    ENDFOREACH()
    SET(${out_var} "${result}" PARENT_SCOPE)
ENDFUNCTION()

set(SOURCE_FILES

        src/instructions/AddressOffset.h
        src/instructions/Instruction.cpp src/instructions/Instruction.h
        src/instructions/Write.cpp src/instructions/Write.h
        src/instructions/Copy.cpp src/instructions/Copy.h
        src/instructions/Load.cpp src/instructions/Load.h
        src/instructions/Init.cpp src/instructions/Init.h
        src/instructions/Calc.cpp src/instructions/Calc.h
        src/instructions/CalcImm.cpp src/instructions/CalcImm.h
        src/instructions/Branch.cpp src/instructions/Branch.h
        src/instructions/Poll.cpp src/instructions/Poll.h
        src/instructions/Loop.cpp src/instructions/Loop.h
        src/instructions/Jump.cpp src/instructions/Jump.h
        src/instructions/Return.cpp src/instructions/Return.h
        src/instructions/Set.cpp src/instructions/Set.h
        src/instructions/Wait.cpp src/instructions/Wait.h
        src/instructions/End.cpp src/instructions/End.h

        src/instructions/virtual/Stack.cpp src/instructions/virtual/Stack.h
        src/instructions/virtual/Call.cpp src/instructions/virtual/Call.h
        src/instructions/virtual/FastCall.cpp src/instructions/virtual/FastCall.h
        src/instructions/virtual/Container.h

        src/Parser.cpp src/Parser.h
        src/Token.cpp src/Token.h
        src/Declaration.cpp src/Declaration.h
        src/Function.cpp src/Function.h
        src/Assembler.cpp src/Assembler.h
        src/Linker.cpp src/Linker.h
        src/EmbeddedResource.h src/BaseRegisters.h
        )

ADD_RESOURCES(embeddedResources
        asm/registers.asm
        asm/config.asm
        asm/api.asm
        asm/init.asm
        asm/stdlib.asm
        )


set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -D_GLIBCXX_DEBUG")

execute_process(COMMAND git describe --tags --always OUTPUT_VARIABLE GIT_REPO_VERSION)

add_executable(rrc-as src/rrcas.cpp ${SOURCE_FILES} ${embeddedResources})
target_compile_definitions(rrc-as PRIVATE "RRCC_VERSION=${GIT_REPO_VERSION}")